3. 「すべてを変更...」をクリック
4. 確認ダイアログで「続ける」をクリック
5. AIR パッケージになった！
これで AIR アプリをもう一度実行したとき、アップデートがうまく行われるようになります。
Mac だとアプリケーションとファイルの関連付けは、拡張子が無くてもファイルタイプとかで認識するので、あんまり「ファイルを関連付けする」的なこととか意識しない気がして、意外にハマり？そうなので以上メモでした。
--
.flv とかも Perian とか入れて Quick Time Player とかに関連づけると幸せです。]]>
Osaka レギュラー等幅 11pt から Menlo Regular 10pt ですが・・・ Eclipse のフォントよりも大きくてガジガジしてるように見えるのは何故でしょう。
Flash がもしかして Cocoa で書かれているわけじゃない？から？なんかよくわかりませんね。Flash は Osaka 等幅の方が良いかもしれないようなそうでもないような。
好みによる、ってことで。w]]>
FileSaveAndReadTest.as
package
{
import com.adobe.serialization.json.JSON;
import flash.display.MovieClip;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.IOErrorEvent;
import flash.events.MouseEvent;
import flash.events.ProgressEvent;
import flash.filesystem.File;
import flash.filesystem.FileMode;
import flash.filesystem.FileStream;
public class FileSaveAndReadTest extends Sprite
{
private var _data:Object;
public function FileSaveAndReadTest()
{
// ステージにボタンがわりにする適当な MovieClip を設置
save_btn.addEventListener(MouseEvent.CLICK, clickHandler);
load_btn.addEventListener(MouseEvent.CLICK, clickHandler);
dummy_btn.addEventListener(MouseEvent.CLICK, clickHandler);
}
private function clickHandler(event:MouseEvent):void
{
// クリックされたとき
var target:MovieClip = MovieClip(event.currentTarget);
switch(target.name)
{
case "save_btn":
if (!_data) return;
// ダミーデータに変更（加算）を加えて保存
_data.test[1] += 10;
save();
break;
case "load_btn":
// データを読み込む
load();
break;
case "dummy_btn":
// ダミーデータを突っ込む
_data = {
"test": [0, 1, 2, 3, 4, 5],
"testtest": "testtest",
"testtesttest": {
"test": [5, 4, 3, 2, 1, 0],
"testtest": "unko"
}
}
break;
}
}
public function save():void
{
// AIR アプリ固有のデータ保存スペース
trace(File.applicationStorageDirectory.url);
var file:File = File.applicationStorageDirectory.resolvePath("sample.json");
// ユーザーのデスクトップにする場合は File.desktopDirectory.resolvePath("sample.json");
// ユーザーのドキュメントディレクトリにする場合は File.documentsDirectory.resolvePath("sample.json");
// ユーザーのホームディレクトリにする場合は File.userDirectory.resolvePath("sample.json");
// アプリケーションのリソースがインストールされているディレクトリにする場合は File.applicationResourceDirectory.resolvePath("sample.json");
// オブジェクトを JSON ファイル形式に変換
var json:String = JSON.encode(_data);
// FileStream 使う
var fs:FileStream = new FileStream();
fs.openAsync(file, FileMode.WRITE); // 書き込みモードで非同期的に開く
fs.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
fs.addEventListener(ProgressEvent.PROGRESS, progressHandler);
//fs.addEventListener(Event.CLOSE, closeHandler);
fs.addEventListener(Event.COMPLETE, saveCompleteHandler);
// 書き込む
fs.writeUTFBytes(json);
}
private function ioErrorHandler(event:IOErrorEvent):void
{
trace(event.text);
}
private function progressHandler(event:ProgressEvent):void
{
}
private function closeHandler(event:Event):void
{
}
private function saveCompleteHandler(event:Event):void
{
// 閉じる
var fs:FileStream = FileStream(event.currentTarget);
fs.removeEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
fs.removeEventListener(ProgressEvent.PROGRESS, progressHandler);
//fs.removeEventListener(Event.CLOSE, closeHandler);
fs.removeEventListener(Event.COMPLETE, loadCompleteHandler);
fs.close();
}
public function load():void
{
// AIR アプリ固有のデータ保存スペース
trace(File.applicationStorageDirectory.url);
var file:File = File.applicationStorageDirectory.resolvePath("sample.json");
var fs:FileStream = new FileStream();
fs.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
fs.addEventListener(ProgressEvent.PROGRESS, progressHandler);
//fs.addEventListener(Event.CLOSE, closeHandler);
fs.addEventListener(Event.COMPLETE, loadCompleteHandler);
fs.openAsync(file, FileMode.READ);
}
private function loadCompleteHandler(event:Event):void
{
var fs:FileStream = FileStream(event.currentTarget);
fs.removeEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
fs.removeEventListener(ProgressEvent.PROGRESS, progressHandler);
//fs.removeEventListener(Event.CLOSE, closeHandler);
fs.removeEventListener(Event.COMPLETE, loadCompleteHandler);
// ファイルを文字列に変換して JSON デコード
var str:String = fs.readUTFBytes(fs.bytesAvailable);
var obj:Object = JSON.decode(str);
// 一応中身の一部トレース
trace(obj.test[1]);
_data = obj;
// 閉じる
fs.close();
}
}
}
カウントダウンが始まっています。いよいよ CS5 ですね。global launch 12 April なんて書いてあるから直訳すると 4 月 12 日世界発売ですけど、 CS4 までは本国で出てから一ヶ月後ぐらいに日本版は発売されていましたので、どうなんですかね。online for exclusive なんでオンライン限定なんですかね。ちなみにどうでもいいですが、僕今月引っ越しもするので金銭的に死にそうです。iPad 貯金切り崩すか悩んでいます。]]>
http://www.youtube.com/user/CS5ORG#p/u
Flash CS5 に関してはこの辺でしょうか。
Adobe Labs - Adobe Flash Professional CS5
http://labs.adobe.com/technologies/flashcs5/
Adobe Flash Platform Blog
http://blogs.adobe.com/flashplatform/
Adobe Flash Professional CS5 * Adobe Flash Professional CS5
http://help.adobe.com/en_US/Flash/CS5/Using/index.html
trick7 - Flash CS5 新機能まるわかりビデオ
http://www.trick7.com/blog/2009/10/08-214224.php
Adobe、Adobe Flash Professional CS5の新機能情報を公開 － MACお宝鑑定団 blog（羅針盤）
http://www.macotakara.jp/blog/index.php?ID=7183
待望のニュース！Flash CS5 で iPhone アプリが開発できる(Flash CS5最新情報の翻訳も) | ClockMaker Blog
http://clockmaker.jp/blog/2009/10/flash-cs5-iphone/
Adobe、Adobe Flash Professional CS5のiPhone書き出し機能「Packager for iPhone」の詳細情報を公開 － MACお宝鑑定団 blog（羅針盤）
http://www.macotakara.jp/blog/index.php?ID=7184
Flash CS5 で iPhone 書き出しのを上手い事パフォーマンス引き出せたら iTunes ストアでリリースしてみたいな。]]>
// MovieClip インスタンスに MouseEvent のように NativeDragEvent を設定
droparea.addEventListener(NativeDragEvent.NATIVE_DRAG_ENTER, nativeDragEnterHandler);
droparea.addEventListener(NativeDragEvent.NATIVE_DRAG_EXIT, nativeDragExitHandler);
droparea.addEventListener(NativeDragEvent.NATIVE_DRAG_DROP, nativeDragDropHandler);
// ドラッグしたまま droparea の上に来たとき
function nativeDragEnterHandler(event:NativeDragEvent):void
{
droparea.alpha = 0.6;
// ドラッグしているアイテムはファイルかどうか
var clipboard:Clipboard = event.clipboard;
if (clipboard.hasFormat(ClipboardFormats.FILE_LIST_FORMAT))
{
// droparea の上でのドロップを許可する
NativeDragManager.acceptDragDrop(droparea);
}
}
// ドラッグしたまま droparea から外れたとき
function nativeDragExitHandler(event:NativeDragEvent):void
{
droparea.alpha = 1.0;
}
// ファイルをドロップしたとき
function nativeDragDropHandler(event:NativeDragEvent):void
{
droparea.alpha = 1.0;
// ドロップしたアイテムを取り出す
var clipboard:Clipboard = event.clipboard;
var files:Array = clipboard.getData(ClipboardFormats.FILE_LIST_FORMAT) as Array;
// ドロップしたアイテムのうち、一つめのファイル
var file:File = files[0];
trace(file.name);
}
ちなみに複数の File インスタンスを得るには最後の取り出しのところを、
for each (var file:File in files)
{
trace(file.name);
}
BPM 計測アプリです。既に似たようなアプリはいくつか発売されているのですが、タップできるエリアが狭かったり、グラフィックでテンションがさがるようなアプリが多くて、楽器の練習時など実際に使っていて、やや不満を感じていました。次第に我慢の限界に達し、自分でデザイン・実装してみることにしました。]]>
当たり前のことですが、ミスタッチ防止というのと、安心感。
大きければ、譜面を読みながらテンポを測る場合、目線を譜面に向かわせておいてもミスなく計測出来ます。タップで集中力を奪わないようにと。
あと、画面を広く占有する大きなボタンがあるだけで「これをタップしろ」というアフォーダンスを、タップボタン君が存分に発揮してくれる気がします。iPhone アプリではいちいち説明書を読め、チュートリアルを見ろ、ということはあまりできないので、視覚でユーザーが想像しやすいようにするのは重要ですよね。
2. 画面右下 i ボタンからのモーダルビューをクローズするボタンは、 i ボタンと同じ右下に
i ボタンを押すと、くるっと画面が回転し、アプリの簡単な紹介ページが開きます。
i ボタンをユーザーが押すとき、ユーザーがどのような持ち方、どの指でタッチするか考えました。
紹介ページでは、サポート Web ページを開くぐらいしか機能がないので、この間にユーザーが本体を右手と左手で持ち変えたり、またはタッチする指を変えたりというのはあまり考えられない気がします。
ユーザーが iPhone を利き手じゃない方の手で持っている、または机に置いている場合、操作を親指以外の指で操作する傾向があると思うので、ボタンを画面のどの辺りに置いても難なくタッチできると思います。
しかし、 iPhone を片手または両手で持って、その親指で操作しているときは、ボタンが画面の上部にあると、やや指から遠いため、タッチしにくい感じがします。結果、画面下部にボタンを配置する事にしました。
また、ユーザーが「気づく」という点においても、画面下からモーダルビューがせり上がってくるタイプのアニメーションが行われるのであれば、モーダルビューの上の方にクローズボタンを置いても良いと思うのですが、今回はくるっと回るアニメーション（画面の見た目がいきなり変わってしまう）なので、タッチした i ボタンに関連のある位置の方がいいと思い、右下に配置しました。
ちなみに iPad の場合は画面解像度が高いので、サポートページ情報ぐらいなのであれば画面遷移はせず、ポップアップ、バルーンなどのインタラクションで行う方が良いと思いました。
3. なんか海外を意識する？
iPhone アプリの売り上げのほとんどは海外と聞いていたので、普段ちらちら見ているものを参考にしながら、想像上の「海外」な感じのデザインパーツを作成していきました。グラデーションや、ノイズな感じとテカリ感のバランスなんですかね。正直難しいですが。
BPM の数値もただ iPhone にインストールされているフォントを使うだけでは面白くないので、グラデーションとグローを加えた、0 から 9 までの png パーツを切り出して、メモリ上に UIImage の NSArray として保持しておき、該当 UIImageView の UIImage を切り替えるという方法で表現しています。
UIImage を作る瞬間ちょっと負荷が高いので、viewDidLoad なタイミングで先に作っといて配列として保持しとく方がよさそうです。
openGL ES とか使った方がもっと高速できるかな？とはいえ現時点でラグもなく、十分早いですが。
でした。
で、これで効果があるかどうかはわかりませんが、色々こうやって無駄に考えていると勉強になっていい感じです。今後考え直す事があればまたバージョンアップや他のアプリでやってみたいです。
というわけで、よろしくお願いします。
→ iPhone アプリ「iBeat - BPM Counter」 紹介ページ
]]>
var i:int;
i ||= 120;
trace(i); // 120var i:int;
i = 5;
i ||= 120;
trace(i); // 5import flash.display.MovieClip;
var mc:MovieClip;
mc = new MovieClipSubClass1();
trace(mc); // MovieClipSubClass1
mc |= new MovieClipSubClass2();
trace(mc); // MovieClipSubClass1var n:int;
n = 2000;
n |= 130;
trace(n); // 20022000 : 11111010000
130 : 000100000102002 : 11111010010// 画面上に Hello World と表示します。
UIFont *font = [UIFont fontWithName:@"HiraKakuProN-W3" size:14.0f];
NSString *str = @"Hello World.";
[str drawAtPoint:CGPointMake(0, 0) withFont:font];
このメソッドは iPhone SDK に存在する、UIKit という高レベルレイヤーのフレームワークが、「カテゴリ」の仕組みを使用して NSString を「拡張」しています。
一般的にクラスを拡張するには、オブジェクト指向の世界では「サブクラス化」が一般的です。Objective-C ではそれに加え、カテゴリによるメソッドの追加という方法があり、サブクラス化の問題点「既存のインスタンスを拡張できない」「メソッド呼び出しのオーバーヘッドが増える」「型が変わってしまう」などを解決しています。
カテゴリは Obejctive-C が、クラスへメソッドの動的な追加ができるようになっているために使用可能になっています。
Objective-C のオープンソースライブラリなどでは、文字列操作用のライブラリの場合、「StringUtils」などのクラスを作るのではなく、NSString をカテゴリで拡張しているのが多く見られます。
カテゴリで既存のクラスを拡張した場合のファイル命名規則は「既存のクラス名＋"+"＋カテゴリ名」が一般的です。
サンプル：文字列から空白文字を除去するための機能を NSString に追加する
XML や JSON の安全なパースの際には空白文字（や、改行文字）を除去します。
// NSString+TrimWhiteSpace.h
@interface NSString (TrimWhiteSpace)
- (NSString *) stringByTrimmingWhitespace;
@end// NSString+TrimWhiteSpace.m
#import “NSString+TrimWhiteSpace.h”
@implementation NSString (TrimWhiteSpace)
- (NSString *) stringByTrimmingWhitespace
{
return [self stringByTrimmingCharactersInSet:[NSCharacterSet whitespaceCharacterSet]];
}
@endNSString *original = @”Hello World”;
NSString *trimmed = [original stringByTrimmingWhitespace];
./flex_sdk_3/frameworks/libs
例えば Macintosh HD 直下においていたら、
/flex_sdk_3/frameworks/libsimport mx.utils.UIDUtil;
trace(UIDUtil.createUID()); //出力：5683E592-DBB5-6FFC-F5EE-6EB1AB7204F3
1. TextLayoutFramework beta を Adobe Lab からダウンロード。
※：学習用に Text Layout Component Examples というサンプルファイルもダウンロードしましょう。
2. Extension Manager CS4 でインストール。
3. Flash CS4 を開いて Flash ドキュメント作成。
4. コンポーネントパネルの「標準コンポーネント」Text Layout をステージにドラッグ。
5. 「TextLayout Sample Text.」と書かれた Text Layout インスタンスが配置される。
6. Window > その他のパネル > Text Layout パネルを開く。
7. 配置したインスタンスを選択したまま、パネル左下「Get from Stage」ボタンを押してステージのインスタンスを同期する。
8. テキストエリアに何か適当に書いた後、「Send to Stage」すると、ステージのインスタンスに編集が反映される。
9. テキストを選択した状態で、パネル右側の操作パネルで色々設定できる。
10. CHARATER の Font を 小塚明朝、 Size を 18、Leading を 200%。Paragraph の Alignment を一番右のアイコン：均等揃え、Just.Rule を East Asian、 ADVANCED CHARACTER の Local を JAPANESE 、Dominant Baseline を Ideographic Center か Ideographic Bottom。そして FLOW の Orientation を Vertical という感じで設定していくと、結構いい感じに。
で、その完成サンプルはこちら。
「/」（半角スラッシュ）は使わないとか、段落の頭は一文字下げるとかの基本も押さえていけば、よりいい感じになっていきそうです。
ただ操作性はまだイマイチ。ルビが振れないのは正直ガッカリ。CS5 で乗るとされる正式版に期待です。
Action Script 3.0 編 I とりあえず表示
AS からも制御可能。HTML でつかう <body> や <p> 、<span> などと同じようなイメージでテキストを階層構造化していくことで文章にします。
<body> は TextFlow インスタンス、 <p> は ParagraphElement インスタンス、 <span> は SpanElement インスタンスに置き換えて、上位のインスタンス（TextFlow）に下位のインスタンス（ParagraphElement、SpanElement）を addChild() することで指定できます。
テキストを入れていったら、TextFlow.flowComposer.addController() で DisplayObejctContainer のツリーに参加させて、TextFlow.flowComposer.updateAllContainers() で内容を更新します。
import flashx.textLayout.elements.TextFlow;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.container.DisplayObjectContainerController;
var tf:TextFlow = new TextFlow();
var p:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
span.text = "ハロー、ワールド。";
tf.addChild(p);
p.addChild(span);
tf.flowComposer.addController(new DisplayObjectContainerController(this, 240, 400));
tf.flowComposer.updateAllContainers();
上の Flash CS4 上で作成したサンプルでは、「縦書き」「日本語禁則処理」「均等揃え」「英語/日本語ベースライン揃え」などを使用しています。これらは formats パッケージなどに用意されている定義クラスを用いることで実現できます。
というわけで、上の Flash CS4 で作った文字組サンプルを再現してみます。
import flashx.textLayout.elements.TextFlow;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.container.DisplayObjectContainerController;
import flashx.textLayout.edit.SelectionManager;
import flashx.textLayout.formats.BlockProgression;
import flashx.textLayout.formats.Direction;
import flashx.textLayout.formats.JustificationRule;
import flashx.textLayout.formats.TextAlign;
import flashx.textLayout.formats.VerticalAlign;
import flash.text.engine.TextBaseline;
var tf:TextFlow = new TextFlow();
tf.color = 0x212121;
tf.fontSize = 18;
tf.fontFamily = "Kozuka Mincho Pro R, Hiragino Mincho Pro W3, MS Mincho, _明朝, _serif";
tf.lineHeight = "200%";
tf.locale = "ja"; // japanese
tf.direction = Direction.LTR;
tf.dominantBaseline = TextBaseline.IDEOGRAPHIC_BOTTOM;
tf.blockProgression = BlockProgression.RL;
tf.justificationRule = JustificationRule.EAST_ASIAN;
tf.interactionManager = new SelectionManager();
tf.textAlign = TextAlign.JUSTIFY;
tf.textAlignLast = TextAlign.LEFT;
tf.paddingRight = 5;
tf.paddingTop = 5;
tf.paddingLeft = 5;
tf.paddingBottom = 5;
var p:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
span.text = "先日縦組みレイアウトのブログサイトで初めて素敵なデザインのサイト「macromarionette」さんを見つけました。Flash Player 10 から導入された Flash Text Engine (FTE)。これをより使いやすくするためのフレームワーク Text Layout Framework (TLF) ベータ版がアドビから提供されたので、これを利用されているそうです。TLF は Flash CS5 から正式に組み込まれるので、正式版で仕様や方式が変わっている/追加されていることは大いにありえるのですが、面白そうなので予習として勉強開始＆メモ。";
tf.addChild(p);
p.addChild(span);
tf.flowComposer.addController(new DisplayObjectContainerController(this, 550, 400));
tf.flowComposer.updateAllContainers();
iPhone Core Audio プログラミングを読み終えました。 iPhone オーディオプログラミングの全てといっても過言ではない内容が詰まった本書。間違いなく iPhone アプリ制作者必読の書です。ちなみに C 言語、Objective-C の知識は多少必要です。]]>
読み進めていくと、随所随所でオーディオプログラミングの基本、サウンドファイルフォーマット、リニアPCM、デシベル、音階、サイン波、音声合成、FM シンセ、FFT などの解説があり、オーディオプロセッシング（オーディオ信号処理）の学習にもなります。
オーディオプログラミングというと、シンセサイザーとか、エフェクター、楽器アプリ作りとかそういうイメージになりがちですが、基本的にはiPhone Core Audio の仕組みと API 解説が主。
iPhone と音にはさまざまな作法があり、とくに Audio Session は、音を扱うアプリならどのアプリにもかかわってくる作法になっているので、ほぼすべての iPhone アプリ製作者にとって必読といえます。
文章による解説がほとんどなので、時間をちゃんと取ってサンプルと見比べながらじっくり読み進めていく覚悟は必要かもしれませんが、iPhone OS API のバグとそのパターン、回避方法が事細かに解説されており、非常に実践的で、捨てるところのない内容です。著者の永野さんは非常によく研究されていると思います。
しかしほんと C 言語での操作のめんどくささは半端ないですね。ActionScript とか Objective-C がなんと楽なことか・・・。普通に第七引数とかを持つ関数がわんさか・・・。
サンプルもスキンを乗せれば普通に有料アプリとして販売できそうなレベル。日本のアプリストアでテルミンや FM シンセがちょとはやりそうな予感。
という感じでした。永野さん曰く名書「詳解 Objective-C 2.0
」を目指したとのことですが、実際素晴らしい内容です。しばらく手放せません。
iPhone OS は Mac OS X との共有部分も多いため、 Mac OS X オーディオプログラミングの基礎固めにもなった気がします。というわけで「Mac Core Audio プログラミング」も書いてほしー。
---
ちなみに僕の iPhone SDK オススメ書籍一覧のページはこちら。
入門、初級、中級、上級としてみました。
]]>
// Video ID を指定
player.cueVideoById(videoId:String, startSeconds:Number, suggestedQuality:String):Void// URL を指定
player.cueVideoByUrl(mediaContentUrl:String, startSeconds:Number):Void// Video ID を指定
player.loadVideoById(videoId:String, startSeconds:Number, suggestedQuality:String):Void// URL を指定
player.loadVideoByUrl(mediaContentUrl:String, startSeconds:Number):Voidpackage
{
import flash.display.DisplayObject;
import flash.display.Loader;
import flash.display.LoaderInfo;
import flash.display.MovieClip;
import flash.events.Event;
import flash.net.URLRequest;
import flash.system.Security;
/**
* Embded YouTube Player Test
*/
public class EmbedYoutubePlayerTest extends MovieClip
{
private var _youtubePlayer:Object;
public function EmbedYoutubePlayerTest()
{
Security.allowDomain("*");
var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.INIT, initHandler);
loader.load(new URLRequest("http://www.youtube.com/apiplayer?version=3"));
}
private function initHandler(event:Event):void
{
_youtubePlayer = Loader(LoaderInfo(event.currentTarget).loader).content as Object;
addChild(_youtubePlayer as DisplayObject);
_youtubePlayer.addEventListener("onReady", onReadyHandler);
_youtubePlayer.addEventListener("onError", onErrorHandler);
_youtubePlayer.addEventListener("onStateChange", onStateChangeHandler);
_youtubePlayer.addEventListener("onPlaybackQualityChange", onPlaybackQualityChangeHandler);
}
private function onReadyHandler(event:Event):void
{
trace("ready", Object(event).data);
_youtubePlayer.setSize(320, 240);
// キューする（スタートボタンが画面中央に表示したまま停止）
//_youtubePlayer.cueVideoById("6hzrDeceEKc");
// すぐさまロードして自動再生
_youtubePlayer.loadVideoById("6hzrDeceEKc");
}
private function onErrorHandler(event:Event):void
{
// error 150 となる場合は、指定した映像が「埋め込み拒否」されている。（どうしようもない）
trace("error", Object(event).data);
}
private function onStateChangeHandler(event:Event):void
{
// state -1 未スタート（SWFが読み込まれたときは -1 の onStateChange イベントが発行される）
// state 0 終了
// state 1 再生中
// state 2 一時停止
// state 3 バッファリング中
// state 5 停止（SWF が読み込まれ、キューに追加されて、再生可能になったら 5 の onStateChange イベントが発行される）
trace("state", Object(event).data);
}
private function onPlaybackQualityChangeHandler(event:Event):void
{
// クオリティを変更した場合
trace("quality", Object(event).data);
}
}
}SWFAddressTest.as
package
{
import flash.display.MovieClip;
import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;
import flash.text.TextFormat;
import SWFAddress;
import SWFAddressEvent;
/**
* for SWFAddress 2.4
*/
public class SWFAddressTest extends MovieClip
{
private var _tf:TextField;
private var _defaultTitle:String;
public function SWFAddressTest()
{
stage.align = StageAlign.TOP_LEFT;
stage.scaleMode = StageScaleMode.NO_SCALE;
_tf = new TextField();
addChild(_tf);
_tf.multiline = true;
_tf.autoSize = TextFieldAutoSize.LEFT;
_tf.width = 200;
_tf.height = stage.stageHeight;
_tf.text = "";
SWFAddress.addEventListener(SWFAddressEvent.INIT, initHandler);
}
private function setButtons():void
{
var names:Array = [
"zero",
"one",
"two/2",
"three/3/3",
"four/4/4/4/",
"popup()",
"href()",
"forward()",
"back()",
"up()",
"go(-2)",
"resetStatus()"
];
for (var i:int = 0; i < names.length; i++)
{
var btn:Sprite = new Sprite();
btn.buttonMode = true;
btn.addEventListener(MouseEvent.CLICK, clickHandler);
btn.graphics.beginFill(0x101226);
btn.graphics.drawRect(0, 0, 100, 30);
btn.name = names[i];
addChild(btn);
btn.x = stage.stageWidth - 120;
btn.y = i * 40 + 20;
var tfm:TextFormat = new TextFormat();
tfm.color = 0xEFEDD9;
var tf:TextField = new TextField();
tf.defaultTextFormat = tfm;
tf.selectable = false;
tf.text = names[i];
btn.addChild(tf);
}
}
private function clickHandler(event:MouseEvent):void
{
var target:Sprite = Sprite(event.currentTarget);
// クエリ文字列が setValue によって消えてしまうので、あればくっつける
var queryString:String = ( SWFAddress.getQueryString() ) ? "?" + SWFAddress.getQueryString() : "";
switch(target.name)
{
case "zero":
case "one":
case "two/2":
case "three/3/3":
case "four/4/4/4/":
SWFAddress.setValue(target.name + queryString);
break;
case "popup()":
tracer("------------------");
tracer("ポップアップウィンドウ起動（option値＝ width=320, height=230, scrollbar=NO）");
tracer("正直動く気がしない");
SWFAddress.popup("http://feb19.jp/blog/archives/000181.php", "popup", "width=320, height=230, scrollbars=NO");
break;
case "href()":
tracer("------------------");
tracer("_target でリンク");
SWFAddress.href("http://feb19.jp/blog/archives/000181.php", "_target");
break;
case "forward()":
tracer("------------------");
tracer("SWFAddress の履歴を一つ進む");
SWFAddress.forward();
break;
case "back()":
tracer("------------------");
tracer("SWFAddress の履歴を一つ戻る");
SWFAddress.back();
break;
case "up()":
tracer("------------------");
tracer("SWFAddress の階層を一つ上がる");
SWFAddress.up();
break;
case "go(-2)":
tracer("------------------");
tracer("SWFAddress の履歴を2つ戻る（引数に 1 を指定すると 1 つ進み、-3 を指定すると 3 つ戻る）");
tracer("履歴が 1 しか残っていなくて、2 つ戻るを指定すると戻らない");
SWFAddress.go(-2);
break;
case "resetStatus()":
tracer("------------------");
tracer("top.document.status = \"\"; を実行（ステータスバーをクリア）");
SWFAddress.resetStatus();
break;
}
}
private function tracer(value:*):void
{
if (value is String)
_tf.text = value + "\n" + _tf.text;
else
_tf.text = value.toString() + "\n" + _tf.text;
}
private function initHandler(event:SWFAddressEvent):void
{
SWFAddress.removeEventListener(SWFAddressEvent.INIT, initHandler);
tracer("------------------");
tracer("parameterNames: " + event.parameterNames);
tracer("parameters: " + event.parameters);
tracer("path: " + event.path);
tracer("pathNames: " + event.pathNames);
tracer("target: " + event.target);
tracer("type: " + event.type);
tracer("value: " + event.value);
tracer("------------------");
// SWF を呼び出す HTML の URL を取得
tracer("getBaseURL: " + SWFAddress.getBaseURL());
// 履歴をセットするか
tracer("getHistory: " + SWFAddress.getHistory());
// クエリ文字列にあるキー名を引数で指定するとその値がとれる。
// クエリ文字列とは URL の後ろにつくことがある「?」以降の文字列。
// ?abc=1&unko=suteki というような感じ。
// この場合は unko キーの値「suteki」を取得できる。
tracer("getParameter: " + SWFAddress.getParameter("unko"));
// クエリ文字列のキー名一覧を配列で取得する。
tracer("getParameterNames: " + SWFAddress.getParameterNames());
// SWFAddress の path 文字列（#以降の文字列）を取得する。クエリ文字列は無視する。
tracer("getPath: " + SWFAddress.getPath());
// SWFAddress の path を配列で取得（「/」を区切りにして配列に格納してくれる）
// 個人的にはアドレスの判別はこれを使うのが便利かつシンプルな気がします。
// クエリ文字列は無視する。
tracer("getPathNames: " + SWFAddress.getPathNames());
// クエリ文字列の取得。（「?」以降の文字列）
tracer("getQueryString: " + SWFAddress.getQueryString());
// ステータスバーの値を取得。
tracer("getStatus: " + SWFAddress.getStatus());
// SWFAddress 文字列（SWFAddressEvent.value）の先頭に「/」がつくか
tracer("getStrict: " + SWFAddress.getStrict());
// ページのタイトルを取得する。
tracer("getTitle: " + SWFAddress.getTitle());
// ページ遷移中にトラッキングする際呼び出す関数 初期値は urchinTracker
tracer("getTracker: " + SWFAddress.getTracker());
// #以降の文字列。クエリ文字列も含む。
tracer("getValue: " + SWFAddress.getValue());
_defaultTitle = SWFAddress.getTitle();
setButtons();
SWFAddress.addEventListener(SWFAddressEvent.CHANGE, changeHandler);
SWFAddress.addEventListener(SWFAddressEvent.EXTERNAL_CHANGE, externalChangeHandler);
SWFAddress.addEventListener(SWFAddressEvent.INTERNAL_CHANGE, internalChangeHandler);
}
private function changeHandler(event:SWFAddressEvent):void
{
tracer("------------------");
// パラメータのキー名一覧を配列で取得
tracer("parameterNames: " + event.parameterNames);
// パラメータ全てを連想配列（Object 型）で取得
tracer("parameters: " + event.parameters);
// SWFAddress の path 文字列（#以降の文字列）を取得する。クエリ文字列は無視。
tracer("path: " + event.path);
// SWFAddress の path を配列で取得（「/」を区切りにして配列に格納してくれる）。
tracer("pathNames: " + event.pathNames);
tracer("target: " + event.target);
tracer("type: " + event.type);
tracer("value: " + event.value);
// .pathNames[0] の値がどうかでウィンドウタイトルを変更する
switch(event.pathNames[0])
{
case "zero": SWFAddress.setTitle( _defaultTitle + " - Content 0" ); break;
case "one": SWFAddress.setTitle( _defaultTitle + " - Content 1" ); break;
case "two": SWFAddress.setTitle( _defaultTitle + " - Content 2" ); break;
case "three": SWFAddress.setTitle( _defaultTitle + " - Content 3" ); break;
case "four": SWFAddress.setTitle( _defaultTitle + " - Content 4" ); break;
default: SWFAddress.setTitle( _defaultTitle + " - Content Unknown" );
}
}
private function externalChangeHandler(event:SWFAddressEvent):void
{
tracer("------------------");
// パラメータのキー名一覧を配列で取得
tracer("parameterNames: " + event.parameterNames);
// パラメータ全てを連想配列（Object 型）で取得
tracer("parameters: " + event.parameters);
// SWFAddress の path 文字列（#以降の文字列）を取得する。クエリ文字列は無視。
tracer("path: " + event.path);
// SWFAddress の path を配列で取得（「/」を区切りにして配列に格納してくれる）。
tracer("pathNames: " + event.pathNames);
tracer("target: " + event.target);
tracer("type: " + event.type);
tracer("value: " + event.value);
}
private function internalChangeHandler(event:SWFAddressEvent):void
{
tracer("------------------");
// パラメータのキー名一覧を配列で取得
tracer("parameterNames: " + event.parameterNames);
// パラメータ全てを連想配列（Object 型）で取得
tracer("parameters: " + event.parameters);
// SWFAddress の path 文字列（#以降の文字列）を取得する。クエリ文字列は無視。
tracer("path: " + event.path);
// SWFAddress の path を配列で取得（「/」を区切りにして配列に格納してくれる）。
tracer("pathNames: " + event.pathNames);
tracer("target: " + event.target);
tracer("type: " + event.type);
tracer("value: " + event.value);
}
}
}